1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
type 'a t =
| Return : 'a -> 'a t
| Map :
{ x : 'a t
; f : 'a -> 'b
}
-> 'b t
| Both : 'a t * 'b t -> ('a * 'b) t
| Apply :
{ f : ('a -> 'b) t
; x : 'a t
}
-> 'b t
| Flag :
{ names : string Ast.Nonempty_list.t
; doc : string
; var : bool ref
}
-> bool t
| Flag_count :
{ names : string Ast.Nonempty_list.t
; doc : string
; var : int ref
}
-> int t
| Named :
{ names : string Ast.Nonempty_list.t
; param : 'a Ast.Param.t
; docv : string option
; doc : string
; var : 'a option ref
}
-> 'a t
| Named_multi :
{ names : string Ast.Nonempty_list.t
; param : 'a Ast.Param.t
; docv : string option
; doc : string
; rev_var : 'a list ref
}
-> 'a list t
| Named_opt :
{ names : string Ast.Nonempty_list.t
; param : 'a Ast.Param.t
; docv : string option
; doc : string
; var : 'a option ref
}
-> 'a option t
| Named_with_default :
{ names : string Ast.Nonempty_list.t
; param : 'a Ast.Param.t
; default : 'a
; docv : string option
; doc : string
; var : 'a option ref
}
-> 'a t
| Pos :
{ pos : int
; param : 'a Ast.Param.t
; docv : string option
; doc : string
; var : 'a option ref
}
-> 'a t
| Pos_opt :
{ pos : int
; param : 'a Ast.Param.t
; docv : string option
; doc : string
; var : 'a option ref
}
-> 'a option t
| Pos_with_default :
{ pos : int
; param : 'a Ast.Param.t
; default : 'a
; docv : string option
; doc : string
; var : 'a option ref
}
-> 'a t
| Pos_all :
{ param : 'a Ast.Param.t
; docv : string option
; doc : string
; rev_var : 'a list ref
}
-> 'a list t
let rec create : type a. a Ast.Arg.t -> a t =
fun (type a) (arg : a Ast.Arg.t) ->
match arg with
| Return a -> Return a
| Map { x; f } ->
let x = create x in
Map { x; f }
| Both (x, y) ->
let x = create x in
let y = create y in
Both (x, y)
| Apply { f; x } ->
let f = create f in
let x = create x in
Apply { f; x }
| Flag { names; doc } -> Flag { names; doc; var = ref false }
| Flag_count { names; doc } -> Flag_count { names; doc; var = ref 0 }
| Named { names; param; docv; doc } -> Named { names; param; docv; doc; var = ref None }
| Named_multi { names; param; docv; doc } ->
Named_multi { names; param; docv; doc; rev_var = ref [] }
| Named_opt { names; param; docv; doc } ->
Named_opt { names; param; docv; doc; var = ref None }
| Named_with_default { names; param; default; docv; doc } ->
Named_with_default { names; param; default; docv; doc; var = ref None }
| Pos { pos; param; docv; doc } -> Pos { pos; param; docv; doc; var = ref None }
| Pos_opt { pos; param; docv; doc } -> Pos_opt { pos; param; docv; doc; var = ref None }
| Pos_with_default { pos; param; default; docv; doc } ->
Pos_with_default { pos; param; default; docv; doc; var = ref None }
| Pos_all { param; docv; doc } -> Pos_all { param; docv; doc; rev_var = ref [] }
;;
module Parse_error = struct
type t =
| Missing_argument :
{ names : string Ast.Nonempty_list.t
; param : 'a Ast.Param.t
; docv : string option
; doc : string
}
-> t
| Missing_positional_argument :
{ pos : int
; param : 'a Ast.Param.t
; docv : string option
; doc : string
}
-> t
end
let finalize (type a) (t : a t) =
let ( let* ) = Result.bind in
let rec eval : type a. a t -> (a Arg_runner.t, Parse_error.t) Result.t =
fun (type a) (arg : a t) : (a Arg_runner.t, Parse_error.t) Result.t ->
match arg with
| Return a -> Ok (Arg_runner.Value a)
| Map { x; f } ->
let* x = eval x in
Ok (Arg_runner.Map { x; f })
| Both (a, b) ->
let* a = eval a in
let* b = eval b in
Ok (Arg_runner.Both (a, b))
| Apply { f; x } ->
let* f = eval f in
let* x = eval x in
Ok (Arg_runner.Apply { f; x })
| Flag { names = _; doc = _; var } -> Ok (Arg_runner.Value var.contents)
| Flag_count { names = _; doc = _; var } -> Ok (Arg_runner.Value var.contents)
| Named { names; param; docv; doc; var } ->
(match var.contents with
| Some value -> Ok (Arg_runner.Value value)
| None -> Error (Parse_error.Missing_argument { names; param; docv; doc }))
| Named_multi { names = _; param = _; docv = _; doc = _; rev_var } ->
Ok (Arg_runner.Value (List.rev rev_var.contents))
| Named_opt { names = _; param = _; docv = _; doc = _; var } ->
Ok (Arg_runner.Value var.contents)
| Named_with_default { names = _; param = _; default; docv = _; doc = _; var } ->
Ok
(Arg_runner.Value
(match var.contents with
| Some value -> value
| None -> default))
| Pos { pos; param; docv; doc; var } ->
(match var.contents with
| Some value -> Ok (Arg_runner.Value value)
| None -> Error (Parse_error.Missing_positional_argument { pos; param; docv; doc }))
| Pos_opt { pos = _; param = _; docv = _; doc = _; var } ->
Ok (Arg_runner.Value var.contents)
| Pos_with_default { pos = _; param = _; default; docv = _; doc = _; var } ->
Ok
(Arg_runner.Value
(match var.contents with
| Some value -> value
| None -> default))
| Pos_all { param = _; docv = _; doc = _; rev_var } ->
Ok (Arg_runner.Value (List.rev rev_var.contents))
in
eval t
;;